Bijlage C. QML-interface

QML-scripts kunnen aangeroepen worden via het contextmenu van de bestandenlijst en kunnen ingesteld worden in het tabblad Gebruikeracties van de instellingendialoog. De scripts die daar worden ingesteld kunnen gebruikt worden als voorbeelden om eigen scripts te programmeren. QML gebruikt JavaScript, hier is het verplichte "Hello World":

import Kid3 1.0

Kid3Script {
  onRun: {
    console.log("Hello world, map is", app.dirName)
    Qt.quit()
  }
}

Als dit script opgeslagen wordt als /pad/naar/Voorbeeld.qml, kan het gebruikerscommando gedefinieerd worden als @qml /pad/naar/Voorbeeld.qml met de naam QML Test en Uitvoer geactiveerd. Het kan gestart worden met het item QML Test in het contextmenu van de bestandenlijst en de uitvoer zal zichtbaar zijn in het venster.

Helaas is het starten van de QML-scripts met qml (bijv. qml -apptype widget -I /usr/lib/kid3/plugins/imports /pad/naar/Voorbeeld.qml) gebroken in recente versies van Qt. Maar kid3-cli biedt een alternatieve manier om een QML-script uit te voeren vanaf de opdrachtregel met zijn commando execute.

kid3-cli -c "execute @qml /pad/naar/Voorbeeld.qml"

Om een lijst te maken van de titels in tag 2 van alle bestanden in de huidige map, kan het volgende script worden gebruikt:

import Kid3 1.0

Kid3Script {
  onRun: {
    app.firstFile()
    do {
      if (app.selectionInfo.tag(Frame.Tag_2).tagFormat) {
        console.log(app.getFrame(tagv2, "title"))
      }
    } while (app.nextFile())
  }
}

Als de map veel bestanden bevat zou zo'n script het gebruikersinterface enige tijd kunnen blokkeren. Voor langere bewerkingen zou het daarom af en toe een pauze moeten hebben. De alternatieve onderstaande implementatie heeft het werk voor een enkel bestand verplaats naar een functie. Deze functie roept zichzelf aan met een timeout van 1 ms aan het eind, gegeven dat er meer bestanden zijn om te verwerken. Dit zal verzekeren dat de GUI actief zal blijven terwijl het script actief is.

import Kid3 1.0

Kid3Script {
  onRun: {
    function doWork() {
      if (app.selectionInfo.tag(Frame.Tag_2).tagFormat) {
        console.log(app.getFrame(tagv2, "title"))
      }
      if (!app.nextFile()) {
        Qt.quit()
      } else {
        setTimeout(doWork, 1)
      }
    }

    app.firstFile()
    doWork()
  }
}

Bij gebruik van app.firstFile() met app.nextFile(), zullen alle bestanden in de huidige map verwerkt worden. Als alleen de geselecteerde bestanden meegenomen moeten worden, gebruik in plaats daarvan firstFile() en nextFile(), dit zijn gemaksfuncties van de component Kid3Script. Het volgende voorbeeld is een script dat alleen het discnummer en de copyrightframes van de geselecteerde bestanden kopieert.

import Kid3 1.1

Kid3Script {
  onRun: {
    function doWork() {
      if (app.selectionInfo.tag(Frame.Tag_2).tagFormat) {
        app.setFrame(tagv2, "*.selected", false)
        app.setFrame(tagv2, "discnumber.selected", true)
        app.setFrame(tagv2, "copyright.selected", true)
        app.copyTags(tagv2)
      }
      if (!nextFile()) {
        Qt.quit()
      } else {
        setTimeout(doWork, 1)
      }
    }

    firstFile()
    doWork()
  }
}

Met Kid3 komen meer voorbeeldscripts en deze zijn al geregistreerd als gebruikercommando's.