Контроль над выполнением

Управляющие операторы позволяют вам контролировать процесс выполнения (о чём говорит само их название).

Управляющие операторы выделяются тёмно-зелёным цветом и жирным начертанием шрифта. Скобки, используемые вместе с ними, выделяются чёрным.

Может ли Черепашка ждать?

Если вы уже немного попрактиковались в программировании в KTurtle, вы могли заметить, что Черепашка может рисовать чересчур быстро. Следующая команда позволяет избежать этого.

жди
жди X

Команда жди указывает Черепашке подождать X секунд.

повтори 36 {
  вперёд 5
  направо 10
  жди 0.5
}

Данный код рисует круг, при этом после каждого шага Черепашка будет ждать пол секунды. Это создаёт впечатление неторопливого движения.

Условное выполнение: «если»

если
если логическое значение { ... }

Код, расположенный между скобками, будет выполнен только если в результате вычисления логического значения получится «истина».

$x = 6
если $x > 5 {
  напиши "$x больше пяти!"
}

В первой строке контейнеру $x присваивается значение 6. Во второй строке оператор сравнения используется для вычисления $x > 5. Если ответом на него будет «истина», 6 больше чем 5, управляющий оператор если позволит выполнить код, расположенный между скобками.

Если нет, другими словами: «иначе»

иначе
если логическое значение { ... } иначе { ... }

иначе может быть дополнением к оператору условного выполнения если. Код между скобками, расположенными после иначе будет выполнен тогда, когда логическое выражение будет «ложь».

сброс
$x = 4
если $x > 5 {
  напиши "$x больше пяти!"
}
иначе
{
  напиши "$x меньше пяти!"
}

Оператор сравнения вычисляет выражение $x > 5. Так как 4 не больше, чем 5, результатом будет «ложь». Это означает, что будет выполнен код между скобками после иначе.

Цикл «пока»

пока
пока логическое значение { ... }

Управляющий оператор пока очень похож на если. Разница в том, что пока будет повторять код, расположенный между скобками, до тех пор, пока логическое выражение не выдаст значение «ложь».

$x = 1
пока $x < 5 {
  вперёд 10
  жди 1
  $x = $x + 1
}

В первой строке $x присваивается 1. На второй строке выполняется сравнение $x < 5. Так как получаемое значение — «истина», оператор пока начнёт выполнять код между скобками, пока не будет получена «ложь». В данном случае код между скобками будет выполнен 4 раза, потому что на каждом прогоне в пятой строке $x будет увеличиваться на 1.

Цикл «повтори»

повтори
повтори число { ... }

Управляющий оператор повтори похож на пока. Разница в том, что повтори повторяет код в скобках заданное число раз.

Считающий цикл «для»

для
для переменная = число до число { ... }

Цикл для — это цикл «со счётчиком», то есть он сохраняет счётчик для вас. Первое число задаёт значение для первого прохода. С каждым проходом это значение увеличивается до того момента, пока не достигнет второго числа.

для $x = 1 до 10 {
  напиши $x * 7
  вперёд 15
}

Каждый раз, когда выполняется код в скобках, значение $x увеличивается на 1, и так до тех пор, пока $x не станет равным 10. Код в скобках выводит на печать произведение $x и 7. После завершения выполнения программы вы увидите на холсте таблицу умножения на 7.

По умолчанию, шаг цикла равен 1. Вы можете задать другой шаг цикла с помощью

для переменная = число до число шаг шаг { ... }

Выход из цикла

прекрати
прекрати

Немедленно завершает выполнение текущего цикла и передаёт управление оператору, следующему сразу после этого цикла.

Остановка выполнения программы

закончить
закончить

Заканчивает выполнение программы.